115 lines
6.1 KiB
CMake
115 lines
6.1 KiB
CMake
include("${PROJECT_SOURCE_DIR}/tools/sdl3-pin.cmake")
|
|
set(sdl_source "${PROJECT_SOURCE_DIR}/build/external/sdl3/SDL3-${EVO_SDL_VERSION}")
|
|
if(NOT EXISTS "${sdl_source}/evo-verified.sha256")
|
|
message(FATAL_ERROR "Prepare SDL explicitly: cmake -P tools/prepare-sdl3.cmake")
|
|
endif()
|
|
file(STRINGS "${sdl_source}/evo-verified.sha256" verified)
|
|
if(NOT verified STREQUAL EVO_SDL_SHA256)
|
|
message(FATAL_ERROR "Prepared SDL does not match the reviewed source pin")
|
|
endif()
|
|
enable_language(C)
|
|
set(SDL_SHARED ON CACHE BOOL "" FORCE)
|
|
set(SDL_STATIC OFF CACHE BOOL "" FORCE)
|
|
set(SDL_TEST_LIBRARY OFF CACHE BOOL "" FORCE)
|
|
set(SDL_TESTS OFF CACHE BOOL "" FORCE)
|
|
set(SDL_EXAMPLES OFF CACHE BOOL "" FORCE)
|
|
set(SDL_INSTALL OFF CACHE BOOL "" FORCE)
|
|
if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
|
|
# Keep Xlib process-lifetime caches reachable across SDL init/quit cycles.
|
|
# Dynamic unloading leaked in the repeated M9.2 lifecycle test (ADR-0078).
|
|
set(SDL_X11_SHARED OFF CACHE BOOL "Link X11 directly for the native client" FORCE)
|
|
endif()
|
|
foreach(feature AUDIO CAMERA JOYSTICK HAPTIC SENSOR GPU)
|
|
set(SDL_${feature} OFF CACHE BOOL "M9.1 scoped subset" FORCE)
|
|
endforeach()
|
|
add_subdirectory("${sdl_source}" "${PROJECT_BINARY_DIR}/sdl3" EXCLUDE_FROM_ALL SYSTEM)
|
|
function(evo_client_runtime target)
|
|
if(WIN32)
|
|
add_custom_command(TARGET ${target} POST_BUILD
|
|
COMMAND "${CMAKE_COMMAND}" -E copy_if_different
|
|
"$<TARGET_FILE:SDL3::SDL3>" "$<TARGET_FILE_DIR:${target}>" VERBATIM)
|
|
endif()
|
|
endfunction()
|
|
if(EVO_BUILD_CLIENT_PROBE)
|
|
add_executable(evo-client-probe experiments/client/main.cpp)
|
|
target_link_libraries(evo-client-probe PRIVATE SDL3::SDL3)
|
|
evo_owned_target(evo-client-probe)
|
|
evo_client_runtime(evo-client-probe)
|
|
if(BUILD_TESTING)
|
|
add_test(NAME client-probe-software COMMAND evo-client-probe --renderer software)
|
|
set_tests_properties(client-probe-software PROPERTIES
|
|
ENVIRONMENT "SDL_VIDEO_DRIVER=dummy" TIMEOUT 20 LABELS "client")
|
|
add_test(NAME client-probe-invalid-driver COMMAND evo-client-probe --renderer evo-invalid)
|
|
set_tests_properties(client-probe-invalid-driver PROPERTIES
|
|
ENVIRONMENT "SDL_VIDEO_DRIVER=dummy" WILL_FAIL TRUE TIMEOUT 20 LABELS "client")
|
|
endif()
|
|
endif()
|
|
|
|
if(EVO_BUILD_CLIENT)
|
|
add_library(evo_render_frame STATIC src/render/frame.cpp)
|
|
target_include_directories(evo_render_frame PUBLIC "${PROJECT_SOURCE_DIR}/include")
|
|
evo_owned_target(evo_render_frame)
|
|
add_library(evo_render_environment STATIC src/render/environment/environment.cpp)
|
|
target_link_libraries(evo_render_environment PUBLIC evo_client_views evo_client_controls evo_render_frame)
|
|
evo_owned_target(evo_render_environment)
|
|
# M9.5 organism projection and the engineering inspector (no text/ImGui dependency).
|
|
add_library(evo_render_organism STATIC src/render/organism/organism.cpp)
|
|
target_link_libraries(evo_render_organism PUBLIC evo_render_environment)
|
|
evo_owned_target(evo_render_organism)
|
|
add_library(evo_client_ui STATIC src/client/ui/organism_inspector.cpp)
|
|
target_link_libraries(evo_client_ui PUBLIC evo_render_organism)
|
|
evo_owned_target(evo_client_ui)
|
|
add_library(evo_client_platform STATIC src/client/platform/application.cpp src/render/sdl_renderer.cpp)
|
|
target_include_directories(evo_client_platform PRIVATE "${PROJECT_SOURCE_DIR}/src")
|
|
target_link_libraries(evo_client_platform PUBLIC evo_render_frame evo_client_controls PRIVATE SDL3::SDL3)
|
|
evo_owned_target(evo_client_platform)
|
|
add_executable(evo-client apps/evo-client/main.cpp)
|
|
target_link_libraries(evo-client PRIVATE evo_client_platform evo_client_ui)
|
|
if(EVO_BUILD_NETWORK)
|
|
# M9.7 remote dev session mode (ADR-0083).
|
|
target_link_libraries(evo-client PRIVATE evo_network_session)
|
|
target_compile_definitions(evo-client PRIVATE EVO_CLIENT_NETWORK=1)
|
|
endif()
|
|
evo_owned_target(evo-client)
|
|
evo_client_runtime(evo-client)
|
|
if(BUILD_TESTING)
|
|
add_executable(evo-client-lifecycle-tests tests/client_lifecycle.cpp tests/client_controls.cpp)
|
|
target_include_directories(evo-client-lifecycle-tests PRIVATE "${PROJECT_SOURCE_DIR}/src")
|
|
target_link_libraries(evo-client-lifecycle-tests PRIVATE evo_client_platform SDL3::SDL3)
|
|
evo_owned_target(evo-client-lifecycle-tests)
|
|
evo_client_runtime(evo-client-lifecycle-tests)
|
|
add_executable(evo-client-environment-tests tests/client_environment.cpp)
|
|
target_link_libraries(evo-client-environment-tests PRIVATE evo_render_environment)
|
|
evo_owned_target(evo-client-environment-tests)
|
|
add_test(NAME client-environment COMMAND evo-client-environment-tests)
|
|
add_executable(evo-client-organism-tests tests/client_organisms.cpp)
|
|
target_link_libraries(evo-client-organism-tests PRIVATE evo_client_ui)
|
|
evo_owned_target(evo-client-organism-tests)
|
|
add_test(NAME client-organisms COMMAND evo-client-organism-tests)
|
|
set_tests_properties(client-organisms PROPERTIES TIMEOUT 60 LABELS "client")
|
|
set_tests_properties(client-environment PROPERTIES TIMEOUT 60 LABELS "client")
|
|
add_test(NAME client-lifecycle COMMAND evo-client-lifecycle-tests)
|
|
add_test(NAME client-smoke COMMAND evo-client --renderer software --frames 3)
|
|
add_test(NAME client-init-failure COMMAND evo-client --frames 1)
|
|
set_tests_properties(client-lifecycle client-smoke PROPERTIES
|
|
ENVIRONMENT "SDL_VIDEO_DRIVER=dummy" TIMEOUT 30 LABELS "client")
|
|
set_tests_properties(client-init-failure PROPERTIES
|
|
ENVIRONMENT "SDL_VIDEO_DRIVER=evo-invalid" WILL_FAIL TRUE TIMEOUT 20 LABELS "client")
|
|
endif()
|
|
endif()
|
|
|
|
if(EVO_BUILD_UI_PROBE)
|
|
include("${PROJECT_SOURCE_DIR}/cmake/EngineeringUi.cmake")
|
|
add_executable(evo-ui-probe experiments/ui/main.cpp)
|
|
target_link_libraries(evo-ui-probe PRIVATE evo_imgui SDL3::SDL3)
|
|
evo_owned_target(evo-ui-probe)
|
|
evo_client_runtime(evo-ui-probe)
|
|
if(BUILD_TESTING)
|
|
add_test(NAME ui-probe COMMAND evo-ui-probe --renderer software)
|
|
add_test(NAME ui-probe-invalid-renderer COMMAND evo-ui-probe --renderer evo-invalid)
|
|
set_tests_properties(ui-probe ui-probe-invalid-renderer PROPERTIES
|
|
ENVIRONMENT "SDL_VIDEO_DRIVER=dummy" TIMEOUT 30 LABELS "client;ui")
|
|
set_tests_properties(ui-probe-invalid-renderer PROPERTIES WILL_FAIL TRUE)
|
|
endif()
|
|
endif()
|