Files
aevolution/tests/cellular_migration_restart.cmake
T
dingo 5e168d67c3
Foundation / checks (ecs) (push) Successful in 2m26s
Foundation / checks (deploy) (push) Successful in 4m12s
Foundation / checks (network) (push) Successful in 20m57s
Foundation / checks (client) (push) Successful in 22m9s
Foundation / checks (tsan) (push) Successful in 28m49s
Foundation / checks (postgres) (push) Successful in 1h5m2s
Foundation / checks (checks) (push) Successful in 1h17m42s
Foundation / postgres-tools (push) Successful in 1m10s
Foundation / server-image (push) Successful in 3m51s
Foundation / image (push) Successful in 4m54s
feat(lifecycle): qualify portable maturing wildlife transfers
2026-10-19 09:09:15 -04:00

38 lines
1.6 KiB
CMake

if(DEFINED ENV{EVO_TEST_TMPDIR} AND NOT "$ENV{EVO_TEST_TMPDIR}" STREQUAL "")
string(RANDOM LENGTH 16 ALPHABET 0123456789abcdef run_id)
set(TEST_DIR "$ENV{EVO_TEST_TMPDIR}/migration-restart-${run_id}")
endif()
file(MAKE_DIRECTORY "${TEST_DIR}")
set(prefix "${TEST_DIR}/pair")
execute_process(COMMAND "${MIGRATION_TEST}" --record "${prefix}" RESULT_VARIABLE recorded)
if(NOT recorded EQUAL 0)
message(FATAL_ERROR "Migration trace preparation failed: ${recorded}")
endif()
execute_process(COMMAND "${MIGRATION_TEST}" --replay "${prefix}" RESULT_VARIABLE replayed)
if(NOT replayed EQUAL 0)
message(FATAL_ERROR "Fresh-process migration replay failed: ${replayed}")
endif()
foreach(variant legacy maturing)
if(variant STREQUAL "legacy")
set(pair "${prefix}")
else()
set(pair "${prefix}.maturing")
endif()
foreach(representation raw pop)
foreach(side source destination)
execute_process(COMMAND "${CMAKE_COMMAND}" -E compare_files
"${pair}.${representation}.${side}.expected"
"${pair}.${representation}.${side}.resumed" RESULT_VARIABLE compared)
if(NOT compared EQUAL 0)
message(FATAL_ERROR "Migration ${variant}/${representation}/${side} diverged across process replay")
endif()
endforeach()
endforeach()
execute_process(COMMAND "${CMAKE_COMMAND}" -E compare_files
"${pair}.pop.continuation.expected" "${pair}.pop.continuation.resumed"
RESULT_VARIABLE continued)
if(NOT continued EQUAL 0)
message(FATAL_ERROR "Transferred ${variant} population interval diverged across process replay")
endif()
endforeach()