Files
aevolution/tools/prepare-sdl3.cmake
T

23 lines
985 B
CMake

cmake_minimum_required(VERSION 3.28)
include("${CMAKE_CURRENT_LIST_DIR}/sdl3-pin.cmake")
set(root "${CMAKE_CURRENT_LIST_DIR}/../build/external/sdl3")
file(MAKE_DIRECTORY "${root}")
if(NOT DEFINED SDL_ARCHIVE)
set(SDL_ARCHIVE "${root}/SDL3-${EVO_SDL_VERSION}.tar.gz")
if(NOT EXISTS "${SDL_ARCHIVE}")
file(DOWNLOAD "${EVO_SDL_URL}" "${SDL_ARCHIVE}" TLS_VERIFY ON
EXPECTED_HASH "SHA256=${EVO_SDL_SHA256}" STATUS result)
list(GET result 0 code)
if(NOT code EQUAL 0)
message(FATAL_ERROR "SDL download failed: ${result}")
endif()
endif()
endif()
file(SHA256 "${SDL_ARCHIVE}" actual)
if(NOT actual STREQUAL EVO_SDL_SHA256)
message(FATAL_ERROR "SDL archive checksum mismatch; refusing extraction")
endif()
file(ARCHIVE_EXTRACT INPUT "${SDL_ARCHIVE}" DESTINATION "${root}")
file(WRITE "${root}/SDL3-${EVO_SDL_VERSION}/evo-verified.sha256" "${actual}\n")
message(STATUS "Prepared SDL ${EVO_SDL_VERSION}; license: ${root}/SDL3-${EVO_SDL_VERSION}/LICENSE.txt")